clear
capture log close

version 9.0
log using final_ecm_web.log, replace
#delimit ;
set more off ;

* ***********************************************************************;
*   Path Name:	  J:\Lobby\Agendas_Project\Death_Penalty\book\chapters\current\ch5_Opinion\analysis2007*;
*   File-Name:      final_ecm_web.do                                    *;
*   Date:           August 13, 2007                                     *;
*   Author:         SDB                                                 *;
*   Purpose:        Estimate quarterly models of public opinion         *;
*   Data Used:      all_qtrly_data.dta                                  *;
*   Output File:    final_ecm_web.log                                   *;
*   Data Output:    none                                                *;
*   Previous File:  final_ecm.do                                        *;
*   Machine:        office                                              *;
* ***********************************************************************;

*use c:\projects\death_penalty\book\data\merged\all_qtrly_data.dta;
use J:\Lobby\Agendas_Project\Death_Penalty\book\data\merged\all_qtrly_data.dta;

summ;

tset qdate;
sort qdate;

replace hom=hom/1000;
tssmooth ma MAhom=hom, window(3,1);


*** Estimate long run relationship ***;
regress netpsm L.MAhom L.net_tone if tin(1976q1,2006q2);
predict lrresids1, resid;
summ netpsm if tin(1976q3,2006q2);

regress netpsm L.MAhom L.net_tone if tin(1976q1,2006q1);
predict lrresids1a, resid;

*** Estimate ecm ***;
regress D.netpsm L.lrresids1 L.D.MAhom L.D.net_tone major if tin(1976q1,2006q2);
predict ecmresid1, resid;
predict yhats if e(sample), xb;
wntestq ecmresid1;
sum D.netpsm if tin(1976q4,2006q2);

list qdate netpsm D.netpsm MAhom D.MAhom;


*** Repeat with pro anti events***;
*** Estimate ecm ***;
regress D.netpsm L.lrresids1 L.D.MAhom L.D.net_tone proevents antievents if tin(1976q1,2006q2);
predict ecmresid1b, resid;
wntestq ecmresid1b;

*** Repeat with separate events***;
*** Estimate ecm ***;
regress D.netpsm L.lrresids1 L.D.MAhom L.D.net_tone sept11 OKcity
    ILmor EX100 DCsnipers ILclemency  if tin(1976q1,2006q2);
predict ecmresid1c, resid;
wntestq ecmresid1c;

*** Repeat with exonerations and executions ***;
*** Estimate long run relationship ***;
regress netpsm L.MAhom L.net_tone L.exonerations L.executions if tin(1976q1,2006q2);
predict lrresids2, resid;

*** Estimate ecm ***;
regress D.netpsm L.lrresids2 L.D.MAhom L.D.net_tone L.D.exonerations L.D.executions
    proevents antievents if tin(1976q1,2006q2);
predict ecmresid2, resid;
wntestq ecmresid2;

*** Repeat for ANTIPSM ***;
*** Estimate long run relationship ***;
regress antipsm L.MAhom L.net_tone if tin(1976q1,2006q2);
predict lrresids3, resid;

*** Estimate ecm ***;
regress D.antipsm L.lrresids3 L.D.MAhom L.D.net_tone major if tin(1976q1,2006q2);
predict ecmresid3, resid;
wntestq ecmresid3;
sum D.antipsm if tin(1976q2,2005q4);

*** Repeat for PROPSM ***;
*** Estimate long run relationship ***;
regress propsm L.MAhom L.net_tone if tin(1976q1,2006q2);
predict lrresids4, resid;

*** Estimate ecm ***;
regress D.propsm L.lrresids4 L.D.MAhom L.D.net_tone major if tin(1976q1,2006q2);
predict ecmresid4, resid;
wntestq ecmresid4;
sum D.propsm if tin(1976q2,2005q4);
clear;

exit;