THE HAPPY ENDING (using ICONT, initial closure factor)
two parallel metal cylinders (1/2 symmetry model), top cylinder pushed down on bottom cylinder
Much Better Results: max. SY stress occurs near the symmetry plane and this gets better with mesh refinement
| Theory:
|
R1 = 0.005 ! radius of (upper) cyl. 1 (m) E1 = 207E9 ! modulus of cyl. 1 (Pa) nu1 = 0.3 ! Poisson's ratio of cyl. 1 R2 = 0.006 ! radius of (lower) cyl. 2 (m) E2 = 110E9 ! modulus of cyl. 2 (Pa) nu2 = 0.33 ! Poisson's ratio of cyl. 2 L = 1 ! both cylinder's length (m)
Pmax = 136.6E+06 Pa In the image above, max. SY = -152 MPa In a more refined mesh, max. SY = -130 MPa |
finish ! these commands were tested in ANSYS 9.0-ED
(354 elements, 971 nodes)
/clear
/plopt,info,1
/triad,lbot
/title, two parallel cylinders in contact
! REF: Juvinall, R. C. and K. M. Marshek,
! Fundamentals of Machine Component Design, 2nd ed.
! John Wiley and Sons, 1991, p.322-323
R1 = 0.005 ! radius of (upper) cyl. 1 (m)
E1 = 207E9 ! modulus of cyl. 1 (Pa)
nu1 = 0.3 ! Poisson's ratio of cyl. 1
R2 = 0.006 ! radius of (lower) cyl. 2 (m)
E2 = 110E9 ! modulus of cyl. 2 (Pa)
nu2 = 0.33 ! Poisson's ratio of cyl. 2
fload = 1000 ! load acting on cyl 1. (N)
! use 1/2 of load for 1/2 symmetry
delta = (1-nu1**2)/E1 + (1-nu2**2)/E2
width = 1.13*SQRT((2*fload*delta)/(1.0*(1/R1+1/R2)))
maxp = 0.564*SQRT(2*fload*(1/R1+1/R2)/(1.0*delta))
/PREP7
!*
ET,1,PLANE183 ! 2D higher-order plane stress element
!*
ET,2,PLANE183 ! 2D higher-order plane stress element
!*
UIMP,1,EX, , ,E1, ! steel properties
UIMP,1,NUXY, , ,nu1,
!*
UIMP,2,EX, , ,E2, ! bronze properties
UIMP,2,NUXY, , ,nu2,
!*
CSYS,1 ! define (lower) cyl 2 geometry
K,1,R2,90
K,2,R2,89
L,1,2
K,3,R2
L,2,3
K,4,R2,-90
L,3,4
CSYS,0
K,5,0,0.99*R2
K,6,kx(2),0.99*R2
K,7
K,8,kx(2)
A,5,6,2,1
A,7,8,6,5
A,8,6,2,3
A,7,8,3,4
AATT, 2, , 2, 0
ASEL,NONE
LOCAL,11,1,0,(R1+R2),0
K,11,R1,-90 ! define (upper) cyl 1 geometry
K,12,R1,-89
L,11,12
K,13,R1
L,12,13
K,14,R1,90
L,13,14
CSYS,0
K,15,0,KY(13)-0.99*R1
K,16,kx(12),KY(13)-0.99*R1
K,17,0,KY(13)
K,18,kx(12),KY(13)
A,15,16,12,11
A,17,18,16,15
A,18,16,12,13
A,17,18,13,14
AATT, 1, , 1, 0
allsel
/wind,1,-1,-0.25,-1,1
/wind,2,-0.25,1,-1,1
/focus,2,0.5*(kx(1)+kx(2))/2,ky(1)
/dist,2,0.55*(kx(2)-kx(1))
aplot
eshape,2
esize,R1/100 ! finer, all-quad. mesh in contact region
lsel,s,,,1,4,3
lsel,a,,,12,15,3
LESIZE,ALL,R1/1000, , ,10,1, , ,1,
lsel,s,,,6,17,11
LESIZE,ALL,R1/300, , ,10,1, , ,1,
lsel,s,,,5,16,11
LESIZE,ALL,R1/300, , ,1/10,1, , ,1,
lsel,all
AMESH,1,5,4
eshape,0
esize,R1/3 ! coarser, free mesh in rest of the model
AMESH,ALL
/COM, CONTACT PAIR CREATION - START
MP,MU,3,0 ! friction for contact = 0
MAT,3
R,3
REAL,3
ET,3,TARGE169
ET,4,CONTA172
RMODIF,3,1,,,1.0,0.1,, ! default real constants for contact
RMODIF,3,7,,,1.0e20,0.0,1.0
RMODIF,3,5,0 ! ICONT = 0, initial closure factor (or adjustment band)
KEYOPT,4,2,0
KEYOPT,4,3,0
KEYOPT,4,5,1 ! Close gap with auto CNOF
KEYOPT,4,6,0
KEYOPT,4,7,0
KEYOPT,4,8,
KEYOPT,4,9,1 ! Exclude both initial penetration or gap and offset
KEYOPT,4,11,
KEYOPT,4,12,0
! Generate the target surface
! target surface is larger & slightly coarser mesh
! both faces are convex, both are higher-order,
! upper surface (Line 14) IS on a stiffer material
LSEL,S,,,1
TYPE,3
NSLL,S,1
ESLN,R,0
ESURF,ALL
allsel
! Generate the contact surface
LSEL,S,,,12
TYPE,4
NSLL,S,1
ESLN,R,0
ESURF,ALL
allsel
/COM, CONTACT PAIR CREATION - END
finish
/SOLU
DK,7, , , ,0,UY, , , , , , ! axial constraint on center of lower cylinder
CSYS,0
lsel,s,loc,x,0
DL,all, ,SYMM ! apply symmetry on left edge of model
lsel,all
FK,17,FY,-fload ! load at center of upper cylinder
!*
ANTYPE,0 ! static analysis
NLGEOM,1 ! include large deformation effects
KBC,0 ! gradually load with automatic timestepping
AUTOTS,on
NSUBST,100,10000,10
OUTRES,BASIC,-10 ! try to save 10 equally spaced results sets.
TIME,1
save
solve
finish
